home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
A-Monthly Disks
/
(c)aau.d64
/
dash game
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
12KB
|
462 lines
1 XZ=51
10 DIM B$(50),P(27),B(27),R(100),S(100)
20 POKE 788,52
100 PRINT "[147]";""
101 POKE 53280,1:POKE 53281,1
110 PRINT " D A S H G A M E"
120 PRINT ""
130 PRINT "CHOOSE WHICH WAY THAT YOU WANT TO PLAY:"
140 PRINT "1. SOLITARE"
150 PRINT "2. AGAINST A FRIEND"
160 PRINT "3. AGAINST THE COMPUTER"
165 PRINT "4. GET INSTRUCTIONS"
170 PRINT " ";:INPUT CC
180 IF CC>4 OR CC<1 THEN 100
181 GOSUB 4000
182 PRINT "[147]";""
185 PRINT "WHAT IS YOUR NAME";:INPUT N1$
186 N1$=LEFT$(N1$,7)
190 ON CC GOTO 200,400,600,2600
200 REM SOLITARE
201 POKE 53280,15
210 GOSUB 5000
220 GOSUB 1000
230 T0=1:S9=0
240 PRINT "WHAT IS YOUR GUESS [157][157][157][157][157][157][157][157][157][157]";:INPUT L$
250 GOSUB 2000
251 S9=S9+SS
255 PRINT " ";
257 PRINT "TURN";T0;N1$;" SCORE";SS;" TOTAL SCORE";S9
260 IF E=999 THEN 300
270 GOSUB 4000
280 T0=T0+1:GOTO 240
300 PRINT " ";
305 POKE 53280,2
310 PRINT "DO YOU WANT TO PLAY AGAIN[160]";N1$:INPUT L$
315 E=0
320 IF MID$(L$,1,1)="Y" THEN 200
330 IF MID$(L$,1,1)<>"N" THEN 300
340 END
400 REM AGAINST A FRIEND
401 POKE 53280,15
405 PRINT "WHAT IS THE NAME OF YOUR FRIEND";:INPUT N2$
406 N2$=LEFT$(N2$,7)
410 GOSUB 5000
420 GOSUB 1000
430 T0=1
435 PRINT " ";
440 PRINT "WHAT IS YOUR GUESS, ";N1$;" [157][157][157][157][157]";:INPUT L$
450 GOSUB 2000
451 S9=S9+SS
455 PRINT " ";
457 PRINT "TURN";T0;N1$;" SCORE";SS;" TOTAL SCORE";S9
460 IF E=999 THEN 550
470 GOSUB 4000
475 PRINT " ";
480 PRINT "WHAT IS YOUR GUESS, ";N2$;" [157][157][157][157][157]";:INPUT L$
490 GOSUB 2000
491 S8=S8+SS
495 PRINT " ";
497 PRINT "TURN";T0;N2$;" SCORE";SS;" TOTAL SCORE";S8
500 IF E=999 THEN 550
510 GOSUB 4000
520 T0=T0+1
530 GOTO 435
550 POKE 53280,2
560 PRINT "DO YOU WANT TO PLAY AGAIN ":INPUT L$
570 E=0
572 IF MID$(L$,1,1)="Y" THEN 410
574 IF MID$(L$,1,1)<>"N" THEN 550
599 END
600 REM AGAINST THE COMPUTER
610 PRINT "[147]":POKE 53281,0:POKE 53280,0
620 PRINT "";
630 PRINT "HOW DO YOU WANT THE COMPUTER TO PLAY"
640 PRINT " 1. EASY"
650 PRINT " 2. MEDIUM"
660 PRINT " 3. HARD"
670 PRINT " 4. VERY HARD"
680 PRINT " 5. EXPERT "
690 PRINT " ";:INPUT HH
695 REM IF HH=5 THEN 2500
700 IF HH<1 OR HH>5 THEN 600
701 IF S8=0 THEN 720
702 PRINT "[147]ENTER (1) FOR NEW SCORE"
703 PRINT " (2) FOR CUMULATIVE SCORE"
704 INPUT " ";SG
705 IF SG<1 OR SG>2 THEN 702
706 IF SG=2 THEN 720
707 S8=0:S9=0
720 GOSUB 5000
730 GOSUB 1000
740 IF HH=3 THEN GOSUB 5600
750 T0=1
760 PRINT "WHAT IS YOUR GUESS, ";N1$;" [157][157][157][157][157]";:INPUT L$
770 GOSUB 2000
790 S9=S9+SS
800 PRINT " ";
810 PRINT "TURN";T0;N1$;SS;" TOTAL SCORE";S9
820 IF E=999 THEN 950
830 GOSUB 4000
835 PRINT " COMPUTER THINKING ";
840 IF HH>1 AND HH<4 THEN GOSUB 3100
850 IF HH=1 THEN GOSUB 3000
860 IF HH=4 THEN GOSUB 2320
865 IF HH=5 THEN GOSUB 3320
870 PRINT " COMPUTER GUESS, [157][157][157][157][157]";L$
880 GOSUB 2000
890 S8=S8+SS
900 PRINT " ";
910 PRINT "TURN";T0;"COMPUTER";SS;" TOTAL SCORE";S8
920 IF E=999 THEN 950
930 GOSUB 4000
935 T0=T0+1
940 GOTO 760
950 POKE 53280,2
960 PRINT "DO YOU WANT TO PLAY AGAIN ";N1$:INPUT L$
970 E=0
972 IF MID$(L$,1,1)="Y" THEN 600
974 IF MID$(L$,1,1)<>"N" THEN 960
999 END
1000 REM PRINT LAYOUT
1001 PRINT "[147]";"";
1005 L1=0:L2=1:PRINT " ";
1010 FOR T=1 TO N5
1020 L1=L1+LEN(B$(T))
1030 IF L1>25 THEN 1080
1040 FOR D=1TOLEN(B$(T)):PRINT"-";:NEXT
1050 PRINT " ";
1060 L$(L2)=L$(L2)+" "+B$(T)
1061 A$(L2)=A$(L2)+" "
1065 FOR I=1 TO LEN(B$(T)):A$(L2)=A$(L2)+"*":NEXT
1070 NEXT T
1075 PRINT "";:RETURN
1080 L1=0:L2=L2+1
1090 PRINT"":PRINT " ";:GOTO 1020
1400 DIM B$(50),P(26),B(26),R(90)
2000 REM ADDING LETTERS
2010 PRINT "";"";
2011 SS=0
2012 IF P(ASC(L$)-64)=1 THEN 2310
2015 P(ASC(L$)-64)=1
2020 FOR T=1 TO L2
2025 PRINT "";
2030 FOR J=1 TO LEN(L$(T ))
2040 IF L$=MID$(L$(T),J,1) THEN 2080
2045 PRINT "";
2050 NEXT J
2060 PRINT""
2070 NEXT T
2071 GOTO 2300
2080 PRINT L$;
2090 SS=SS+1:IFJ=1 THEN A$(T)=L$+MID$(A$(T),2,LEN$(A(T)))
2095 JJ=J
2100 IF J>1 THEN A$(T)=MID$(A$(T),1,J-1)+L$+MID$(A$(T),J+1,LEN(A$(T)))
2105 IF J=1 THEN Q=1:GOTO 2150
2110 FOR Q=J TO 1 STEP -1
2120 IF MID$(A$(T),Q,1)=" " THEN 2140
2130 NEXT Q
2135 Q=1
2140 IF MID$(L$(T),Q,1)<>" " THEN 2290
2150 FOR QQ=Q+1 TO LEN(L$(T))
2160 IF MID$(L$(T),QQ,1)=" " THEN 2190
2170 IF MID$(L$(T),QQ,1)<>MID$(A$(T),QQ,1) THEN 2290
2180 NEXT QQ
2190 SS=SS+5
2200 FOR Q=1 TO L2
2210 IF A$(Q)<>L$(Q) THEN 2290
2220 NEXT Q
2230 SS=SS+5
2240 E=999
2290 GOTO 2050
2300 REM
2310 RETURN
2320 REM MOVE WITH HIGHEST POINTS
2321 SE=-1
2340 FOR MO=65 TO 90
2342 FOR Q=1 TO L2:C$(Q)=A$(Q):NEXT
2350 Q$=CHR$(MO)
2355 SS=0
2360 IF P(ASC(Q$)-64)=1 THEN 2485
2365 FOR T=1 TO L2
2370 FOR J=1 TO LEN(L$(T ))
2375 IF Q$=MID$(L$(T),J,1) THEN 2395
2380 NEXT J
2385 NEXT T
2390 GOTO 2485
2395 SS=SS+1:IFJ=1 THEN C$(T)=Q$+MID$(C$(T),2,LEN(C$(T)))
2400 IF J>1 THEN C$(T)=MID$(C$(T),1,J-1)+Q$+MID$(C$(T),J+1,LEN(C$(T)))
2405 IF J=1 THEN Q=1:GOTO 2435
2410 FOR Q=J TO 1 STEP -1
2415 IF MID$(C$(T),Q,1)=" " THEN 2430
2420 NEXT Q
2425 Q=1
2430 IF MID$(L$(T),Q,1)<>" " THEN 2480
2435 FOR QQ=Q+1 TO LEN(L$(T))
2440 IF MID$(L$(T),QQ,1)=" " THEN 2455
2445 IF MID$(L$(T),QQ,1)<>MID$(C$(T),QQ,1) THEN 2480
2450 NEXT QQ
2455 IF NX=0 THEN SS=SS+5
2460 FOR Q=1 TO L2
2465 IF C$(Q)<>L$(Q) THEN 2480
2470 NEXT Q
2475 SS=SS+5
2480 GOTO 2380
2485 IF SS<SE THEN 2490
2488 SE=SS:PM=MO
2490 NEXT MO
2495 L$=CHR$(PM)
2499 RETURN
2500 REM INSTRUCTIONS
2510 PRINT "NOBODY'S PERFECT!!!"
2520 GOSUB 4000
2530 GOTO 600
2600 REM INSTRUCTIONS
2610 PRINT "[147]"
2620 POKE 53281,7:POKE 53280,7
2630 PRINT " D A S H G A M E"
2640 PRINT " * * * INSTRUCTIONS * * *"
2650 PRINT:PRINT
2660 PRINT "THIS IS A LETTER GUESSING GAME."
2665 PRINT "THE COMPUTER PICKS A SAYING FROM IT'S "
2670 PRINT "DATA BANKS. THE PLAYERS TRY TO GUESS "
2671 PRINT "THE SAYING ONE LETTER AT A TIME. YOU"
2672 PRINT "GET ONE POINT FOR EACH TIME THE LETTER"
2673 PRINT "APPEARS, FIVE POINTS FOR EACH WORD "
2674 PRINT "COMPLETED AND FIVE POINTS FOR "
2675 PRINT "COMPLETING THE ENTIRE SAYING. "
2676 FORT=1TO3000:NEXT:PRINT
2677 PRINT "YOU CAN PLAY BY YOURSELF (SOLITARE),"
2678 PRINT "AGAINST A FRIEND OR AGAINST"
2679 PRINT " THE COMPUTER. "
2680 FORT=1TO2000:NEXT:PRINT
2681 PRINT "IF YOU CHOOSE TO PLAY AGAINST THE "
2683 PRINT "COMPUTER, THERE ARE FIVE LEVELS "
2687 PRINT"OF DIFICULTY TO CHOOSE FROM."
2688 PRINT "(THE COMPUTER CHEATS ON THE TOP TWO "
2689 PRINT "LEVELS.) "
2690 GOSUB 4000
2700 PRINT "[147]"
2710 PRINT "WHEN YOU GET TIRED OF THE SAYINGS IN "
2712 PRINT "THE DATA BANK, YOU CAN SUBSTITUTE SOME"
2714 PRINT "OF YOUR OWN. JUST REPLACE THE DATA "
2716 PRINT "STATEMENTS STARTING ON LINE 6000 WITH"
2718 PRINT "YOUR OWN SAYINGS. YOU MUST PUT A "
2720 PRINT "COMMA AFTER EACH WORD AND THE LETTERS"
2722 PRINT "XX AT THE END OF THE SAYING."
2723 FORT=1TO2000:NEXT: PRINT
2724 PRINT "IF YOU CHANGE THE NUMBER OF SAYINGS IN "
2726 PRINT "THE DATA BANK YOU MUST CHANGE THE "
2728 PRINT "VALUE OF XZ IN LINE 1. (THERE ARE NOW"
2730 PRINT "51 SAYINGS IN THE DATA BANK.)"
2732 GOSUB 4000
2734 GOTO 100
2800 STOP
3000 REM COMPUTER PICKS RANDOMLY
3010 X=INT(RND(1)*26+1)
3020 IF P(X)=1 THEN 3010
3030 L$=CHR$(X+64)
3040 PRINT "";L$
3050 REM
3060 RETURN
3100 REM COMPUTER PICKS BY DISTRIBUTION
3110 FOR T=1 TO 26
3120 IF P(B(T)-64)=0 THEN 3140
3130 NEXT T
3135 T=T-1
3140 L$=CHR$(B(T))
3150 PRINT "";L$
3160 REM
3170 RETURN
3320 REM MOVE WITH HIGHEST POINTS
3321 SE=-100
3340 FOR MO=65 TO 90
3342 FOR Q=1 TO L2:C$(Q)=A$(Q):NEXT
3350 Q$=CHR$(MO)
3355 SS=-110
3360 IF P(ASC(Q$)-64)=1 THEN 3485
3361 SS=0
3365 FOR T=1 TO L2
3370 FOR J=1 TO LEN(L$(T ))
3375 IF Q$=MID$(L$(T),J,1) THEN 3395
3380 NEXT J
3385 NEXT T
3386 S(MO)=SS
3390 GOTO 3485
3395 SS=SS+1:IFJ=1 THEN C$(T)=Q$+MID$(C$(T),2,LEN(C$(T)))
3400 IF J>1 THEN C$(T)=MID$(C$(T),1,J-1)+Q$+MID$(C$(T),J+1,LEN(C$(T)))
3405 IF J=1 THEN Q=1:GOTO 3431
3410 FOR Q=J TO 1 STEP -1
3415 IF MID$(C$(T),Q,1)=" " THEN 3430
3420 NEXT Q
3425 Q=1
3430 IF MID$(L$(T),Q,1)<>" " THEN 3480
3431 NX=0
3435 FOR QQ=Q+1 TO LEN(L$(T))
3440 IF MID$(L$(T),QQ,1)=" " THEN 3455
3445 IF MID$(L$(T),QQ,1)<>MID$(C$(T),QQ,1) THEN NX=NX+1
3450 NEXT QQ
3455 IF NX=0 THEN SS=SS+5
3456 IF NX=1 THEN SS=SS-7
3460 FOR Q=1 TO L2
3465 IF C$(Q)<>L$(Q) THEN 3480
3470 NEXT Q
3475 SS=SS+5
3480 GOTO 3380
3485 IF SS<SE THEN 3490
3488 SE=SS:PM=MO
3490 NEXT MO
3495 L$=CHR$(PM)
3499 RETURN
4000 REM SPACE BAR
4010 PRINT "";
4020 PRINT " HIT SPACE BAR TO CONTINUE [146]";
4030 GET W$:AD=RND(1)
4031 IF W$<>" " THEN 4030
4038 PRINT "";
4039 PRINT " ";
4040 RETURN
5000 RESTORE:REM READING
5001 FOR T=1 TO 26:READB(T):NEXT
5002 FOR T=1 TO 10:L$(T)="": A$(T)="":NEXT
5003 FOR T=1 TO 26:P(T)=0:NEXT
5005 FOR T=1 TO 100:R(T)=0:NEXT
5010 PRINT "READING DATA"
5020 X=INT(RND(1)*XZ+1)
5030 FOR TT=1 TO X
5050 T=1
5060 READ B$(T)
5070 IF B$(T)="XX" THEN 5090
5080 T=T+1:GOTO 5060
5090 N5=T-1
5100 NEXT TT
5110 FOR T=1 TO N5
5120 FOR TT=1 TO LEN(B$(T))
5130 R0=ASC(MID$(B$(T),TT,1))-64
5140 R(R0)=1
5150 NEXT TT
5160 NEXT T
5170 FOR T=1 TO 26
5180 IF R(T)=0 THEN P(T)=1
5190 NEXT T
5300 RETURN
5400 RESTORE:REM RESEARCH
5401 FOR T=1 TO 26:READB(T):NEXT
5410 PRINT "COMPUTER IS STUDYING"
5430 FOR TT=1 TO XZ
5450 T=1
5460 READ B$(T)
5470 IF B$(T)="XX" THEN 5490
5471 FOR OP=1 TO LEN(B$(T))
5472 D$=MID$(B$(T),OP,1)
5473 R(ASC(D$))=R(ASC(D$))+1+5/LEN(B$(T))
5474 NEXT OP
5480 T=T+1:GOTO 5460
5490 NEXT TT
5500 FOR T=1 TO 26
5501 BB=0:BN=0
5505 FOR RT=65 TO 90
5510 IF R(RT)<BB THEN 5530
5520 BB=R(RT):BN=RT
5530 NEXT RT
5540 B(T)=BN:R(BN)=0
5550 PRINT T,BN,CHR$(BN)
5560 NEXT T
5561 GOSUB 4000
5570 RETURN
5600 REM DIST FOR THIS PUZZLE
5605 PRINT "COMPUTER STUDYING"
5610 FOR T=1 TO 100:R(T)=0:NEXT
5630 FOR TT=1 TO N5
5671 FOR OP=1 TO LEN(B$(TT))
5672 D$=MID$(B$(TT),OP,1)
5673 R(ASC(D$))=R(ASC(D$))+1+5/LEN(B$(TT))
5674 NEXT OP
5690 NEXT TT
5700 FOR T=1 TO 26
5701 BB=0:BN=0
5705 FOR RT=65 TO 90
5710 IF R(RT)<BB THEN 5730
5720 BB=R(RT):BN=RT
5730 NEXT RT
5740 B(T)=BN:R(BN)=0
5760 NEXT T
5770 RETURN
5900 DATA 69,84,79,73,65,83,78
5905 DATA 72,82,76,71
5910 DATA 70,85,87,77,89,67,68,80,66,86
5920 DATA 75,81,88,74,90
6000 DATA IF,YOU,DO,NOT,BET,THEN,YOU,CANNOT,WIN,XX
6001 DATA THESE,ARE,THE,GOOD,OLD,DAYS,XX
6002 DATA HE,WHO,SLINGS,MUD,GENERALLY,LOSES,GROUND,XX
6003 DATA I,WOULD,RATHER,HAVE,A,BOTTLE,IN,FRONT,OF,ME,THAN,A,FRONTAL
6004 DATA LOBOTOMY,XX
6005 DATA ONE,CAN,GET,JUST,AS,DRUNK,ON,WATER,AS,ON,CAN,ON,LAND,XX
6006 DATA IN,AMERICA,THERE,ARE,TWO,CLASSES,OF,TRAVEL,FIRST,AND,WITH,CHILDREN,XX
6007 DATA THE,EASIEST,WAY,TO,MAKE,MONEY,IS,TO,STOP,LOSING,IT,XX
6008 DATA ONE,MANS,CEILING,IS,ANOTHER,MANS,FLOOR,XX
6009 DATA IF,EVERYTHING,SEEMS,TO,BE,GOING,YOUR,WAY,THEN,YOU,ARE,PROBABLY
6010 DATA IN,THE,WRONG,LANE,XX
6011 DATA IF,YOU,ARE,STUCK,WITH,A,LEMON,THEN,YOU,SHOULD,MAKE,LEMONADE,XX
6012 DATA VIRTUE,IS,THE,FAILURE,TO,ACHIEVE,VICE,XX
6013 DATA THE,SIMPLEST,EXPLANATION,IS,THAT,IT,DOES,NOT,MAKE,SENSE,XX
6014 DATA PRACTICAL,POLITICS,CONSISTS,IN,IGNORING,FACTS,XX
6015 DATA WHEN,IN,DOUBT,BLAME,THE,SCHOOL,SYSTEM,XX
6029 DATA ALWAYS,STORE,BEER,IN,A,DARK,PLACE,XX
6030 DATA A,MOTHERS,DELUSIONS,ABOUT,HER,CHILDRENS,BEAUTY
6040 DATA INTELLIGENCE,AND,GOODNESS,KEEP,HER,FROM,DROWNING,THEM,AT,BIRTH
6050 DATA XX
6060 DATA LITTLE,GIRLS,AND,BUTTERFLIES
6070 DATA NEED,NO,EXCUSE,XX
6100 DATA GULLIBILITY,IS,THE,KEY,TO,ALL
6110 DATA ADVENTURES,XX
6120 DATA GROW,OLD,ALONG,WITH,ME,THE
6130 DATA BEST,IS,YET,TO,BE,XX
6140 DATA TAXES,ARE,NOT,LEVIED,FOR,THE
6150 DATA BENEFIT,OF,THE,TAXED
6160 DATA XX
6170 DATA NEVER,UNDERESTIMATE,THE
6180 DATA POWER,OF,HUMAN,STUPIDITY
6200 DATA XX
6201 DATA IT,IS,EASIER,TO,SUFFER,IN
6202 DATA SILENCE,IF,YOU,ARE,SURE,SOMEONE,IS,WATCHING,XX
6204 DATA PEOPLE,GENERALLY,QUARREL,BECAUSE,THEY,CANNOT,ARGUE,XX
6205 DATA PUNCTUALITY,IS,THE,ART,OF,GUESSING,CORRECTLY,HOW,LATE,THE,OTHER
6206 DATA PERSON,IS,GOING,TO,BE,XX
6208 DATA TO,STAY,YOUNG,REQUIRES,THE,UNCEASING,CULTIVATION,OF,THE,ABILITY
6209 DATA TO,UNLEARN,OLD,FALSEHOODS,XX
6210 DATA SECRECY,IS,THE,BEGINNING,OF,TYRANNY,XX
6211 DATA THE,GREATEST,PRODUCTIVE,FORCE,IS,HUMAN,SELFISHNESS,XX
6212 DATA MIDDLE,AGE,IS,WHEN,YOU,HAVE,THE,CHOICE,OF,TWO,TEMPTATIONS,AND,YOU
6213 DATA CHOOSE,THE,ONE,THAT,WILL,GET,YOU,HOME,EARLIER,XX
6214 DATA THE,ULTIMATE,SIN,OF,THE,MIND,IS,THE,FAILURE,TO,PAY,ATTENTION,XX
6215 DATA THE,MISFORTUNES,HARDEST,TO,BEAR,ARE,THOSE,WHICH,NEVER,HAPPEN,XX
6216 DATA TILTING,AT,WINDMILLS,HURTS,YOU,MORE,THAN,THE,WINDMILLS,XX
6217 DATA THERE,IS,NO,SUCH,THING,AS,A,LITTLE,GARLIC,XX
6218 DATA EVEN,MODERATION,OUGHT,NOT,TO,BE,PRACTICED,TO,EXCESS,XX
6219 DATA HE,THAT,MARRIES,FOR,MONEY,EARNS,IT,XX
6220 DATA I,WONDER,WHERE,MOTHERS,LEARNED,ALL,THE,THINGS,THEY,TELL,THEIR
6221 DATA DAUGHTERS,NOT,TO,DO,XX
6222 DATA OURS,IS,A,WORLD,OF,NUCLEAR,GIANTS,AND,ETHICAL,INFANTS,XX
6223 DATA NEVER,TRY,TO,OUTSTUBBORN,A,CAT
6224 DATA XX
6225 DATA A,SUCCESSFUL,POLITICIAN,IS,ONE,WHO,CAN,GET,IN,THE,PUBLIC,EYE
6226 DATA WITHOUT,IRRITATING,IT,XX
6227 DATA YIELD,TO,TEMPTATION,OR,IT,MAY,NOT,PASS,YOUR,WAY,AGAIN
6228 DATA XX
6229 DATA NOTHING,IS,SO,FULL,OF,VICTORY,AS,PATIENCE,XX
6230 DATA THE,FIRST,ART,OF,BEING,A,PARENT,IS,SLEEPING,WHEN,THE,KIDS,ARE,NOT
6240 DATA LOOKING,XX
6241 DATA MORE,THAN,ONE,PESSIMIST,GOT,THAT,WAY,BY,FINANCING,AN,OPTIMIST,XX
6242 DATA THE,TOUGHEST,PART,OF,POLITICS,IS,TO,SATISFY,THE,VOTER,WITHOUT
6243 DATA GIVING,HIM,WHAT,HE,WANTS,XX
6244 DATA A,RUMOR,IS,AS,HARD,TO,UNSPREAD,AS,BUTTER,XX
6245 DATA ANYONE,WHO,STILL,THINKS,THAT,THE,SKY,IS,THE,LIMIT,HAS,NO
6246 DATA IMAGINATION,XX
6247 DATA THE,BEST,WAY,OUT,IS,ALWAYS,THROUGH,XX
6248 DATA THE,EASIEST,WAY,TO,AVOID,TEMPTATION,IS,PUBLICLY,XX
6249 DATA THE,DOOR,TO,HAPPINESS,OPENS,OUTWARD,XX
6250 DATA HE,WHO,HESITATES,IS,SOMETIMES,SAVED,XX
6251 DATA IMAGINATION,IS,MORE,IMPORTANT,THAN,KNOWLEDGE,XX
6252 DATA MORAL,INDIGNATION,IS,JELOUSY,WITH,A,HALO,XX